[BACK]Return to maketars CVS log [TXT][DIR] Up to [local] / src / distrib / sets
File: [local] / src / distrib / sets / maketars (download)

Revision 1.12, Wed Apr 26 02:11:54 2000 UTC (24 years, 1 month ago) by deraadt
Branch: MAIN
CVS Tags: OPENBSD_3_0_BASE, OPENBSD_3_0, OPENBSD_2_9_BASE, OPENBSD_2_9, OPENBSD_2_8_BASE, OPENBSD_2_8, OPENBSD_2_7_BASE, OPENBSD_2_7
Changes since 1.11: +4 -4 lines 

sync

#!/bin/csh -f
#	$OpenBSD: maketars,v 1.12 2000/04/26 02:11:54 deraadt Exp $


set RELEASE=$1

if ( "X${RELEASE}" == "X" ) then
	echo "Usage: `basename $0` <OSREVISION>"
	exit 1
endif

if (! $?RELEASEDIR) then
	echo RELEASEDIR must be set
	exit 1
endif

if (! $?DESTDIR) then
	echo DESTDIR must be set
	exit 1
endif

set arch=`machine`
set listsdir=`pwd`/lists
set tardir=$RELEASEDIR
set fsdir=$DESTDIR

cd $fsdir

set lists=(base comp etc game)
# SPECIAL: man misc

foreach setname ($lists)
	echo -n "${setname}: "
	cat $listsdir/$setname/mi $listsdir/$setname/md.${arch} | sort | \
	    pax -w -d | gzip -9 > ${tardir}/${setname}${RELEASE}.tgz
	echo    "done."
end

set setname=man
echo -n "${setname}: "
grep ${arch} $listsdir/man/md_share | \
    cat $listsdir/$setname/mi $listsdir/$setname/md.${arch} - | sort | \
    pax -w -d | gzip -9 > ${tardir}/${setname}${RELEASE}.tgz
echo    "done."

set setname=misc
echo -n "${setname}: "
grep -v ${arch} $listsdir/man/md_share | \
    cat $listsdir/$setname/mi $listsdir/$setname/md.${arch} - | sort | \
    pax -w -d | gzip -9 > ${tardir}/${setname}${RELEASE}.tgz
echo    "done."